EventHubBack/test/logic_event_recurring_tests.erl

-module(logic_event_recurring_tests).
-include_lib("eunit/include/eunit.hrl").
-include("records.hrl").

setup() ->
  mnesia:start(),
  mnesia:create_table(user, [
    {attributes, record_info(fields, user)},
    {ram_copies, [node()]}
  ]),
  mnesia:create_table(calendar, [
    {attributes, record_info(fields, calendar)},
    {ram_copies, [node()]}
  ]),
  mnesia:create_table(event, [
    {attributes, record_info(fields, event)},
    {ram_copies, [node()]}
  ]),
  mnesia:create_table(recurrence_exception, [
    {attributes, record_info(fields, recurrence_exception)},
    {ram_copies, [node()]}
  ]),
  ok.

cleanup(_) ->
  mnesia:delete_table(recurrence_exception),
  mnesia:delete_table(event),
  mnesia:delete_table(calendar),
  mnesia:delete_table(user),
  mnesia:stop(),
  ok.

logic_event_recurring_test_() ->
  {foreach,
    fun setup/0,
    fun cleanup/1,
    [
      {"Create recurring event test", fun test_create_recurring_event/0},
      {"Create recurring event invalid RRULE test", fun test_create_recurring_invalid/0},
      {"Get occurrences test", fun test_get_occurrences/0},
      {"Cancel occurrence test", fun test_cancel_occurrence/0},
      {"Get occurrences with cancelled test", fun test_occurrences_with_cancelled/0},
      {"Materialize for booking test", fun test_materialize_for_booking/0}
    ]}.

create_test_user_and_calendar() ->
  UserId = base64:encode(crypto:strong_rand_bytes(16), #{mode => urlsafe, padding => false}),
  User = #user{
    id = UserId,
    email = <<"test@example.com">>,
    password_hash = <<"hash">>,
    role = user,
    status = active,
    created_at = calendar:universal_time(),
    updated_at = calendar:universal_time()
  },
  mnesia:dirty_write(User),

  {ok, Calendar} = logic_calendar:create_calendar(UserId, <<"Test Calendar">>, <<"">>, manual),
  {UserId, Calendar#calendar.id}.

test_create_recurring_event() ->
  {UserId, CalendarId} = create_test_user_and_calendar(),
  Title = <<"Weekly Meeting">>,
  StartTime = {{2026, 6, 1}, {10, 0, 0}},
  Duration = 60,
  RRule = #{<<"freq">> => <<"WEEKLY">>, <<"interval">> => 1},

  {ok, Event} = logic_event:create_recurring_event(UserId, CalendarId, Title, StartTime, Duration, RRule),

  ?assertEqual(CalendarId, Event#event.calendar_id),
  ?assertEqual(Title, Event#event.title),
  ?assertEqual(recurring, Event#event.event_type).

test_create_recurring_invalid() ->
  {UserId, CalendarId} = create_test_user_and_calendar(),
  Title = <<"Invalid">>,
  StartTime = {{2026, 6, 1}, {10, 0, 0}},
  Duration = 60,
  InvalidRRule = #{<<"freq">> => <<"YEARLY">>, <<"interval">> => 1},

  {error, invalid_rrule} = logic_event:create_recurring_event(
    UserId, CalendarId, Title, StartTime, Duration, InvalidRRule
  ).

test_get_occurrences() ->
  {UserId, CalendarId} = create_test_user_and_calendar(),
  StartTime = {{2026, 6, 1}, {10, 0, 0}},
  RRule = #{<<"freq">> => <<"WEEKLY">>, <<"interval">> => 1},

  {ok, Event} = logic_event:create_recurring_event(
    UserId, CalendarId, <<"Weekly">>, StartTime, 60, RRule
  ),

  RangeEnd = {{2026, 6, 29}, {10, 0, 0}},
  {ok, Occurrences} = logic_event:get_occurrences(UserId, Event#event.id, RangeEnd),

  ?assertEqual(5, length(Occurrences)).

test_cancel_occurrence() ->
  {UserId, CalendarId} = create_test_user_and_calendar(),
  StartTime = {{2026, 6, 1}, {10, 0, 0}},
  RRule = #{<<"freq">> => <<"WEEKLY">>, <<"interval">> => 1},

  {ok, Event} = logic_event:create_recurring_event(
    UserId, CalendarId, <<"Weekly">>, StartTime, 60, RRule
  ),

  CancelTime = {{2026, 6, 8}, {10, 0, 0}},
  {ok, cancelled} = logic_event:cancel_occurrence(UserId, Event#event.id, CancelTime).

test_occurrences_with_cancelled() ->
  {UserId, CalendarId} = create_test_user_and_calendar(),
  StartTime = {{2026, 6, 1}, {10, 0, 0}},
  RRule = #{<<"freq">> => <<"WEEKLY">>, <<"interval">> => 1},

  {ok, Event} = logic_event:create_recurring_event(
    UserId, CalendarId, <<"Weekly">>, StartTime, 60, RRule
  ),

  CancelTime = {{2026, 6, 8}, {10, 0, 0}},
  {ok, cancelled} = logic_event:cancel_occurrence(UserId, Event#event.id, CancelTime),

  RangeEnd = {{2026, 6, 29}, {10, 0, 0}},
  {ok, Occurrences} = logic_event:get_occurrences(UserId, Event#event.id, RangeEnd),

  ?assertEqual(4, length(Occurrences)),

  Starts = [O || {virtual, O} <- Occurrences],
  ?assertNot(lists:member(CancelTime, Starts)).

test_materialize_for_booking() ->
  {UserId, CalendarId} = create_test_user_and_calendar(),
  StartTime = {{2026, 6, 1}, {10, 0, 0}},
  RRule = #{<<"freq">> => <<"WEEKLY">>, <<"interval">> => 1},

  {ok, Event} = logic_event:create_recurring_event(
    UserId, CalendarId, <<"Weekly">>, StartTime, 60, RRule
  ),

  OccurrenceStart = {{2026, 6, 8}, {10, 0, 0}},
  SpecialistId = <<"specialist123">>,

  {ok, Instance} = logic_event:materialize_for_booking(
    Event#event.id, OccurrenceStart, SpecialistId
  ),

  ?assertEqual(Event#event.id, Instance#event.master_id),
  ?assertEqual(OccurrenceStart, Instance#event.start_time),
  ?assertEqual(SpecialistId, Instance#event.specialist_id),
  ?assertEqual(true, Instance#event.is_instance).