-module(admin_handler_users_tests).
-include_lib("eunit/include/eunit.hrl").

setup() ->
  ok = meck:new(cowboy_req, [non_strict]),
  ok = meck:new(handler_auth, [non_strict]),   % вместо auth
  ok = meck:new(core_user, [non_strict]),
  ok.

cleanup(_) ->
  meck:unload(core_user),
  meck:unload(handler_auth),
  meck:unload(cowboy_req).

admin_users_test_() ->
  {setup, fun setup/0, fun cleanup/1, [
    {"GET /admin/users with valid admin token returns 200 and list of users", fun test_list_users/0},
    {"GET /admin/users with non-admin token returns 403", fun test_list_users_forbidden/0},
    {"POST /admin/users returns 405", fun test_wrong_method/0}
  ]}.

test_list_users() ->
  ok = meck:expect(cowboy_req, method, fun(_) -> <<"GET">> end),
  ok = meck:expect(handler_auth, authenticate,
    fun(Req) -> {ok, <<"admin1">>, Req} end),
  User = #{
    id => <<"user1">>,
    email => <<"user@test.com">>,
    role => <<"user">>,
    status => <<"active">>,
    created_at => {{2025,4,27},{12,0,0}},
    updated_at => {{2025,4,27},{12,30,0}}
  },
  ok = meck:expect(core_user, list_users, fun() -> {ok, [User]} end),
  ok = meck:expect(cowboy_req, reply, fun(Code, Headers, Body, Req) ->
    put(test_reply, {Code, Headers, Body, Req})
                                      end),
  {ok, _, _} = admin_handler_users:init(req, []),
  {Status, _, RespBody, _} = erase(test_reply),
  ?assertEqual(200, Status),
  Users = jsx:decode(RespBody, [return_maps]),
  ?assertEqual(1, length(Users)),
  ?assertEqual(<<"user1">>, maps:get(<<"id">>, hd(Users))).

test_list_users_forbidden() ->
  ok = meck:expect(cowboy_req, method, fun(_) -> <<"GET">> end),
  ok = meck:expect(handler_auth, authenticate,
    fun(Req) -> {error, 403, <<"Admin access required">>, Req} end),
  ok = meck:expect(cowboy_req, reply, fun(Code, Headers, Body, Req) ->
    put(test_reply, {Code, Headers, Body, Req})
                                      end),
  {ok, _, _} = admin_handler_users:init(req, []),
  {Status, _, RespBody, _} = erase(test_reply),
  ?assertEqual(403, Status),
  ?assertEqual(#{<<"error">> => <<"Admin access required">>}, jsx:decode(RespBody, [return_maps])).

test_wrong_method() ->
  ok = meck:expect(cowboy_req, method, fun(_) -> <<"POST">> end),
  ok = meck:expect(cowboy_req, reply, fun(Code, Headers, Body, Req) ->
    put(test_reply, {Code, Headers, Body, Req})
                                      end),
  {ok, _, _} = admin_handler_users:init(req, []),
  {Status, _, RespBody, _} = erase(test_reply),
  ?assertEqual(405, Status),
  ?assertEqual(#{<<"error">> => <<"Method not allowed">>}, jsx:decode(RespBody, [return_maps])).