Stage 5

src/logic/logic_review.erl

@@ -0,0 +1,216 @@
+-module(logic_review).
+-include("records.hrl").
+
+-export([create_review/5, get_review/2, list_reviews/3, list_user_reviews/1,
+  update_review/3, delete_review/2, hide_review/2, unhide_review/2]).
+-export([can_review/3, update_target_rating/2, can_moderate_review/2]).
+
+%% Создание отзыва
+create_review(UserId, TargetType, TargetId, Rating, Comment) ->
+  case target_exists(TargetType, TargetId) of
+    true ->
+      case can_review(UserId, TargetType, TargetId) of
+        {ok, true} ->
+          case core_review:has_user_reviewed(UserId, TargetType, TargetId) of
+            false ->
+              case core_review:create(UserId, TargetType, TargetId, Rating, Comment) of
+                {ok, Review} ->
+                  update_target_rating(TargetType, TargetId),
+                  {ok, Review};
+                Error ->
+                  Error
+              end;
+            true ->
+              {error, already_reviewed}
+          end;
+        {ok, false} ->
+          {error, cannot_review};
+        {error, _} = Error ->
+          Error
+      end;
+    false ->
+      {error, target_not_found}
+  end.
+
+%% Получение отзыва
+get_review(UserId, ReviewId) ->
+  case core_review:get_by_id(ReviewId) of
+    {ok, Review} ->
+      case is_admin(UserId) orelse Review#review.status =:= visible of
+        true -> {ok, Review};
+        false -> {error, access_denied}
+      end;
+    Error ->
+      Error
+  end.
+
+%% Список отзывов для цели
+list_reviews(UserId, TargetType, TargetId) ->
+  case core_review:list_by_target(TargetType, TargetId) of
+    {ok, Reviews} ->
+      case is_admin(UserId) of
+        true -> {ok, Reviews};
+        false -> {ok, [R || R <- Reviews, R#review.status =:= visible]}
+      end;
+    Error ->
+      Error
+  end.
+
+%% Список отзывов пользователя
+list_user_reviews(UserId) ->
+  core_review:list_by_user(UserId).
+
+%% Обновление отзыва (только автор)
+update_review(UserId, ReviewId, Updates) ->
+  io:format("Updating review ~p with ~p~n", [ReviewId, Updates]),
+  case core_review:get_by_id(ReviewId) of
+    {ok, Review} ->
+      case Review#review.user_id =:= UserId of
+        true ->
+          % Преобразуем бинарные ключи в атомы
+          ValidUpdates = lists:filtermap(fun
+                                           ({<<"rating">>, V}) when is_integer(V), V >= 1, V =< 5 -> {true, {rating, V}};
+                                           ({rating, V}) when is_integer(V), V >= 1, V =< 5 -> {true, {rating, V}};
+                                           ({<<"comment">>, V}) when is_binary(V) -> {true, {comment, V}};
+                                           ({comment, V}) when is_binary(V) -> {true, {comment, V}};
+                                           (_) -> false
+                                         end, Updates),
+          io:format("Valid updates: ~p~n", [ValidUpdates]),
+          case ValidUpdates of
+            [] -> {error, no_valid_updates};
+            _ ->
+              case core_review:update(ReviewId, ValidUpdates) of
+                {ok, Updated} ->
+                  update_target_rating(Review#review.target_type, Review#review.target_id),
+                  {ok, Updated};
+                Error -> Error
+              end
+          end;
+        false -> {error, access_denied}
+      end;
+    Error -> Error
+  end.
+
+%% Удаление отзыва (автор или админ)
+delete_review(UserId, ReviewId) ->
+  case core_review:get_by_id(ReviewId) of
+    {ok, Review} ->
+      case Review#review.user_id =:= UserId orelse is_admin(UserId) of
+        true ->
+          TargetType = Review#review.target_type,
+          TargetId = Review#review.target_id,
+          case core_review:delete(ReviewId) of
+            {ok, deleted} ->
+              update_target_rating(TargetType, TargetId),
+              {ok, deleted};
+            Error ->
+              Error
+          end;
+        false ->
+          {error, access_denied}
+      end;
+    Error ->
+      Error
+  end.
+
+hide_review(UserId, ReviewId) ->
+  case can_moderate_review(UserId, ReviewId) of
+    true ->
+      case core_review:hide(ReviewId) of
+        {ok, Review} ->
+          update_target_rating(Review#review.target_type, Review#review.target_id),
+          {ok, Review};
+        Error ->
+          Error
+      end;
+    false ->
+      {error, access_denied}
+  end.
+
+unhide_review(UserId, ReviewId) ->
+  case can_moderate_review(UserId, ReviewId) of
+    true ->
+      case core_review:unhide(ReviewId) of
+        {ok, Review} ->
+          update_target_rating(Review#review.target_type, Review#review.target_id),
+          {ok, Review};
+        Error ->
+          Error
+      end;
+    false ->
+      {error, access_denied}
+  end.
+
+%% Проверка, может ли пользователь оставить отзыв
+can_review(UserId, TargetType, TargetId) ->
+  case TargetType of
+    event ->
+      case core_booking:get_by_event_and_user(TargetId, UserId) of
+        {ok, Booking} ->
+          {ok, Booking#booking.status =:= confirmed};
+        {error, not_found} ->
+          {ok, false}
+      end;
+    calendar ->
+      {ok, true};
+    _ ->
+      {ok, false}
+  end.
+
+%% Проверка, может ли пользователь модерировать отзыв (скрыть/раскрыть)
+can_moderate_review(UserId, ReviewId) ->
+  case is_admin(UserId) of
+    true ->
+      true;
+    false ->
+      % Проверяем, является ли пользователь владельцем календаря/события
+      case core_review:get_by_id(ReviewId) of
+        {ok, Review} ->
+          case Review#review.target_type of
+            event ->
+              case core_event:get_by_id(Review#review.target_id) of
+                {ok, Event} ->
+                  case core_calendar:get_by_id(Event#event.calendar_id) of
+                    {ok, Calendar} -> Calendar#calendar.owner_id =:= UserId;
+                    _ -> false
+                  end;
+                _ -> false
+              end;
+            calendar ->
+              case core_calendar:get_by_id(Review#review.target_id) of
+                {ok, Calendar} -> Calendar#calendar.owner_id =:= UserId;
+                _ -> false
+              end;
+            _ -> false
+          end;
+        _ -> false
+      end
+  end.
+
+%% Внутренние функции
+target_exists(event, EventId) ->
+  case core_event:get_by_id(EventId) of
+    {ok, _} -> true;
+    _ -> false
+  end;
+target_exists(calendar, CalendarId) ->
+  case core_calendar:get_by_id(CalendarId) of
+    {ok, _} -> true;
+    _ -> false
+  end;
+target_exists(_, _) -> false.
+
+is_admin(UserId) ->
+  case core_user:get_by_id(UserId) of
+    {ok, User} -> User#user.role =:= admin;
+    _ -> false
+  end.
+
+update_target_rating(event, EventId) ->
+  {Avg, Count} = core_review:get_average_rating(event, EventId),
+  io:format("Updating event ~p rating: avg=~p, count=~p~n", [EventId, Avg, Count]),
+  core_event:update(EventId, [{rating_avg, Avg}, {rating_count, Count}]);
+update_target_rating(calendar, CalendarId) ->
+  {Avg, Count} = core_review:get_average_rating(calendar, CalendarId),
+  core_calendar:update(CalendarId, [{rating_avg, Avg}, {rating_count, Count}]);
+update_target_rating(_, _) -> ok.